t-sql에서 'execute'를 사용하여 변수로 값을 설정하는 방법은 무엇입니까?

t-sql에서 'execute'를 사용하여 변수로 값을 설정하는 방법은 무엇입니까?

DECLARE @dbName nvarchar(128) = 'myDb'
DECLARE @siteId int 
exec ('SELECT TOP 1 @siteId = Id FROM ' + @dbName + '..myTbl')  
select @siteId

위 스크립트를 실행하면 다음 오류가 발생합니다.

Msg 137, Level 15, State 1, Line 1
Must declare the scalar variable "@siteId".

(1 row(s) affected)

왜 그리고 어떻게 그것을 고치나요?

감사해요.

출력 매개 변수는 sp_executesql과 함께 사용할 수 있습니다.

DECLARE @dbName nvarchar(128) = 'myDb'
DECLARE @siteId int 
DECLARE @SQL nvarchar(max) = N'SELECT TOP 1 @outputFromExec = Id FROM ' + quotename(@dbName) + N'..myTbl'
exec sp_executesql @SQL, N'@outputFromExec int out', @siteId out
select @siteId

동적 SQL이 SQL을 호출하는 외부와 다른 범위이므로 @siteid가 인식되지 않습니다.

동적 SQL 외부에 있는 temp table/table 변수를 사용해야 합니다.

DECLARE @dbName nvarchar(128) = 'myDb'
DECLARE @siteId TABLE (siteid int)

INSERT @siteId
exec ('SELECT TOP 1 Id FROM ' + @dbName + '..myTbl')  

select * FROM @siteId

참고: ORDER BY가 없는 TOP은 의미가 없습니다.표에는 자연적, 암시적 또는 본질적 순서가 없습니다.모든 주문은 가장 바깥쪽의 ORDER BY에 의해서만 보장됩니다.

당신은 아래와 같이 시도할 수 있습니다.

DECLARE @sqlCommand NVARCHAR(4000)
DECLARE @ID INT
DECLARE @Name NVARCHAR(100)
SET @ID = 4
SET @sqlCommand = 'SELECT @Name = [Name]
FROM [AdventureWorks2014].[HumanResources].[Department]
WHERE DepartmentID = @ID'
EXEC sp_executesql @sqlCommand, N'@ID INT, @Name NVARCHAR(100) OUTPUT',
@ID = @ID, @Name = @Name OUTPUT
SELECT @Name ReturnedName

출처: blog.sqlauthority.com

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
-- =============================================
-- Author:      Andrew Foster
-- Create date: 28 Mar 2013
-- Description: Allows the dynamic pull of any column value up to 255 chars from regUsers table
-- =============================================
ALTER PROCEDURE dbo.PullTableColumn
(
    @columnName varchar(255),
    @id int
)
AS
BEGIN
    -- SET NOCOUNT ON added to prevent extra result sets from
    -- interfering with SELECT statements.
    SET NOCOUNT ON;

    DECLARE @columnVal TABLE (columnVal nvarchar(255));

    DECLARE @sql nvarchar(max);
    SET @sql = 'SELECT ' + @columnName + ' FROM regUsers WHERE id=' + CAST(@id AS varchar(10));
    INSERT @columnVal EXEC sp_executesql @sql;

    SELECT * FROM @columnVal;
END
GO

실행 쿼리를 약간 변경하면 문제가 해결됩니다.

DECLARE @dbName nvarchar(128) = 'myDb'
DECLARE @siteId int 
exec ('SELECT TOP 1 **''@siteId''** = Id FROM ' + @dbName + '..myTbl')  
select @siteId

언급URL : https://stackoverflow.com/questions/7229070/how-to-set-value-to-variable-using-execute-in-t-sql